微机原理与接口技术
本文记录微机原理与接口技术课程中的四个实验,均在 Tpc-zk-II 集成开发环境与微机原理与接口技术实验箱上完成,汇编程序在 IDE 中编译并下载运行,涵盖 8259 中断、8253 定时/计数、8255 并行接口与 ADC0809 模数转换四部分。实验前需检查各种插线是否稳固(USB 接口、电路板插稳后会亮灯指示),并在 IDE 中完成硬件检测这一步,IDE 对汇编代码的报错详细到行,逐行核对即可
| 实验 | 实验目的 |
|---|---|
| 系统中断实验 | 掌握 PC 机中断处理系统的基本原理,学会编写中断服务程序 |
| 8253 定时器计数器实验 | 掌握 8253 的计数特点和编程方法,掌握工作方式 3 的原理与编程方法 |
| 8255 并行 I/O 实验 | 了解 8255 芯片结构及编程方法,了解 8255 输入/输出实验方法 |
| 模/数转换器 0809 实验 | 了解模/数转换的基本原理,掌握 ADC0809 的使用方法 |
实验环境
Tpc-zk-II集成开发环境- 微机原理与接口技术实验箱
# 系统中断
# 中断处理原理
系统上电时,ROM BIOS 对 8259A 的主片和从片要执行初始化命令
中断向量和中断向量表:
CPU 获取中断类型码的方法有三种
- CPU 内部中断时,由硬件电路自动提供
- 软中断
INT n在指令的代码中提供 - 可屏蔽的外中断 INTR 通过硬件(8259A)提供
对于 PC/AT 及 286 以上微机,内部又扩展了一片 8259 中断控制器,IRQ2 用于两片 8259 之间级连,对外可以提供 16 个中断源
| 中断源 | 中断类型号 | 中断功能 |
|---|---|---|
| IRQ0 | 08H | 时钟 |
| IRQ1 | 09H | 键盘 |
| IRQ2 | 0AH | 保留 |
| IRQ3 | 0BH | 串行口2 |
| IRQ4 | 0CH | 串行口1 |
| IRQ5 | 0DH | 硬盘 |
| IRQ6 | 0EH | 软盘 |
| IRQ7 | 0FH | 并行打印机 |
| IRQ8 | 70H | 实时时钟 |
| IRQ9 | 71H | 用户中断 |
| IRQ10 | 72H | 保留 |
| IRQ11 | 73H | 保留 |
| IRQ12 | 74H | 保留 |
| IRQ13 | 75H | 协处理器 |
| IRQ14 | 76H | 硬盘 |
| IRQ15 | 77H | 保留 |
本实验使用 IRQ3,中断类型号为 0BH,需要把服务程序的入口地址写入 0BH 号向量(位于 0000:002CH,低字为偏移、高字为段址);硬件中断的服务程序结束前还要向 20H 端口发出 EOI 命令
# 中断服务程序
实验电路直接用手动单脉冲作为中断请求信号(只需连接一根导线),要求每按一次开关产生一次中断,在屏幕上显示 NEUQ 2023!if Winter comes,can Spring be far behind?
插上实验箱电源,USB 接口连接主机,连接实验箱总线/MIRQx和单脉冲1/正脉冲,开启实验箱电源,在 Tpc-zk-II 集成开发环境中进行硬件检测后,编写汇编代码
interrupt.asm
data segment
info db 'NEUQ 2023!if Winter comes,can Spring be far behind?', 0ah, 0ah, '$'
data ends
code segment
assume cs:code, ds:data
start:
mov ax,cs
mov ds,ax
mov dx,offset int3
mov ah,25h
mov al,0bh
int 21h
in al,21h
and al,0f7h
out 21h,al
here:jmp here
int3 proc
push ax
push ds
push dx
sti
mov ax,data
mov ds,ax
mov dx,offset info
mov ah,9
int 21h
mov al,20h
out 20h,al
cli
pop dx
pop ds
pop ax
iret
int3 endp
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
程序先用 25H 号功能设置 0BH 号中断向量,再把 21H 端口的 D3 位清零以开放 IRQ3,之后死循环等待中断;服务程序显示字符串、发出 EOI 后由 IRET 返回
编译运行后,每次按下单脉冲开关将在屏幕上显示上述信息:
# 8253 定时器计数器
# 8253 工作原理
8253/8254 内部结构包含三个 16 位减一计数单元和一个控制寄存器:
各地址信号组合功能:
8253/8254 的编程命令:作为可编程器件,8253/8254 通过命令字来控制其工作方式,命令字有两类
- 初始化编程命令:用于设定计数器的功能、工作方式
- 锁存读出命令:用于读出计数器中的计数值,或计数器的状态(8254)
8253/8254 的初始化控制字:
8253 具有三个计数器 CNT0、CNT1、CNT2,还有一个控制寄存器,它们各占一个地址(由引脚 A1、A0 确定);在每一个计数器 CNTi 中,有三个部分构成,初值寄存器 CR、减一计数器 CE 和输出锁存器 OL
8253/8254 的初始化编程:初始化编程操作的顺序是,先向控制寄存器写入命令字,然后写入初值。如果是 16 位初值,必须先写入低 8 位初值,再写入高 8 位初值;最后输出锁存命令(读计数器的计数值),将当前计数器的计数值捕捉到输出锁存器 OL 中
8253/8254 共有六种工作方式,实验中使用的是方式 2 和方式 3
- 方式 2 为频率发生器:写入初值后计数单元从 N 开始减一计数,减到 1 时
OUT输出一个时钟周期的低电平脉冲,随后自动重装初值,因此每 N 个时钟周期出现一次负脉冲 - 方式 3 为方波发生器:减一计数到初值的一半时
OUT翻转一次,输出对称或近似对称的方波,周期同样为 N 个时钟周期,最适合做分频
# 计数实验
实验流程:
count.asm
data segment
io0 equ 280h
io1 equ 281h
io2 equ 282h
iok equ 283h
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,iok
mov al,14h
out dx,al
mov dx,io0
mov al,9
out dx,al
r1:mov dx,io0
in al,dx
call dis
mov ah,1
int 16h
jz r1
mov ah,4ch
int 21h
dis proc
push ax
push dx
add al,30h
mov dl,al
mov ah,2
int 21h
pop dx
pop ax
ret
dis endp
here:jmp here
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
控制字 14H = 0001 0100B:D7D6=00 选中 CNT0,D5D4=01 表示只读写低 8 位,D3D2D1=010 为方式 2,D0=0 为二进制计数。随后向 280H(CNT0)写入初值 09H,计数器开始减一计数
按图连接电路,将计数器 0 设置为方式 2,计数器初值为 N(N<=0FH),用手逐个输入单脉冲,编程使计数值在屏幕上显示,用逻辑笔观察 OUT0 电平变化(当输入 N+1 个脉冲后 OUT0 变高电平)
| 接线 | |
|---|---|
| 8254/CLK0 | 单脉冲/正脉冲 |
| 8254/CS | I/O译码/Y0(280H---287H) |
| 8254/OUT0 | LED显示/L7 或 逻辑笔 |
| 8254/GATE0 | +5V |
点击运行,记录计数过程
# 定时实验
timer.asm
data segment
io0 equ 280h
io1 equ 281h
io2 equ 282h
iok equ 283h
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,iok
mov al,36h
out dx,al
mov dx,io0
mov ax,1000
out dx,al
mov al,ah
out dx,al
mov dx,iok
mov al,76h
out dx,al
mov dx,io1
mov ax,1000
out dx,al
mov al,ah
out dx,al
here:jmp here
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
控制字 36H = 0011 0110B:D7D6=00 选中 CNT0,D5D4=11 表示先读写低 8 位再读写高 8 位,D3D2D1=011 为方式 3,D0=0 为二进制计数;初值 1000 分两次写入,先送低字节再送高字节,均写到 280H。随后向控制口写入 76H = 0111 0110B,即选中 CNT1、先低后高、方式 3、二进制计数,初值同样为 1000,写到 281H
按下图连接电路,将计数器 0、计数器 1 分别设置工作方式,CLK0 连接时钟 1MHZ,由 T0 进行 1000 分频后变为 1000HZ,再由 T1 进行 1000 分频后得 1HZ
| 接线 | |
|---|---|
| 8254/CLK0 | 时钟/1MHz |
| 8254/CS | I/O译码/Y0(280H---287H) |
| 8254/OUT0 | LED显示/L7 或 逻辑笔 |
| 8254/GATE0,GATE1 | +5V |
| 8254/OUT1 | 逻辑笔 |
运行程序,可以看到指示灯如下描述闪烁:高低电平每变化一次,计数加一,计数由两位二进制组成,如
- 在
0时刻,计数为00,两个指示灯均暗 - 在
1时刻,高低电平变化,计数变为01,第一个指示灯暗,第二个指示灯亮 - 在
2时刻,高低电平变化,计数为10,第一个指示灯亮,第二个指示灯暗 - 在
3时刻,计数为11,两个指示灯均亮 - 在
4时刻,计数为00,两个指示灯均暗
# 8255 并行输入输出
8255 有 A、B、C 三个 8 位端口和一个控制寄存器。实验箱用 I/O 译码的 Y1 选中该芯片,基址为 288H,即 288H 为 A 口、289H 为 B 口、28AH 为 C 口、28BH 为控制口。方式控制字写往控制口:D7=1 为特征位,D6D5、D2 选 A 组、B 组方式,D4、D1 决定 A 口、B 口输入/输出,D3、D0 决定 C 口高 4 位与低 4 位的输入/输出;D7=0 时写入的是 C 口位操作命令,D3D2D1 选位、D0 决定置位还是复位
# 方式 0 输入输出
8255 方式 0 为基本输入输出方式,将 C 口作为输入,输入信号由 8 个逻辑电平开关提供;A 口作为输出,其内容由发光二极管显示。将实验线路连接好后编程,从 8255 的 C 口输入数据,再从 A 口输出:
| 接线 | |
|---|---|
| 8255/JP8(PC7---PC0) | 逻辑开关/JP1(K7---K0) |
| 8255/JP6(PA7---PA0) | LED显示/JP2(L7---L0) |
| 8255/CS | I/O译码/Y1(288H---28FH) |
io3-1.asm
data segment
ioa equ 288h
iob equ 289h
ioc equ 28ah
iok equ 28bh
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,iok
mov al,89h
out dx,al
s:
mov dx,ioc
in al,dx
mov dx,ioa
out dx,al
mov ah,1
int 16h
jz s
mov ah,4ch
int 21h
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
控制字 89H = 1000 1001B:D7=1 为方式控制字,D6D5=00 表示 A 组方式 0、D4=0 表示 A 口输出、D3=0 表示 PC7~PC4 输出;D2=0 表示 B 组方式 0、D1=0 表示 B 口输出、D0=1 表示 PC3~PC0 输入
连接实验箱执行代码,每个逻辑电平开关对应一个 LED 灯,打开逻辑电平开关时其对应的 LED 灯亮起
# 方式 1 选通
方式 1 为选通输入输出方式,A 口、B 口要借用 C 口的三根线作联络信号:输入时用 /STB、IBF、INTR,输出时用 /OBF、/ACK、INTR。数据传送由硬件联络信号控制,CPU 不必反复查询端口
8255 方式 1 为选通输入输出方式。B 口 PB2~PB0 接逻辑电平开关 K2~K0,A 口接 LED 显示电路 L0~L7,PC2(/STB) 与单脉冲的负脉冲端相连。编程按下单脉冲按键产生一个负脉冲输入到 PC2,用发光二极管 LEDi 点亮显示 K2~K0 开关的状态:
| 接线 | |
|---|---|
| 8255/PB2---PB0 | 逻辑开关/K2---K0 |
| 8255/JP6(PA7---PA0) | LED显示/JP2(L7---L0) |
| 8255/PC2 | 单脉冲/负脉冲 |
| 8255/CS | I/O译码/Y1(288H---28FH) |
io3-2.asm
data segment
ioa equ 288h
iob equ 289h
ioc equ 28ah
iok equ 28bh
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,offset int3
mov ax,250bh
int 21h
in al,21h
and al,0f7h
out 21h,al
mov dx,iok
mov al,0b0h
out dx,al
mov al,9
out dx,al
ll: jmp ll
int3: push ax
push dx
push ds
mov ax,data
mov ds,ax
mov dx,ioa
in al,dx
mov dl,al
mov ah,2
int 21h
mov al,20h
out 20h,al
pop ds
pop dx
pop ax
iret
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
控制字 0B0H = 1011 0000B:D7=1 为方式控制字,D6D5=01 表示 A 组方式 1、D4=1 表示 A 口输入、D3=0 表示 PC7 与 PC6 为输入;D2=0 表示 B 组方式 0、D1=0 表示 B 口输出、D0=0 表示 PC3~PC0 输出。随后写入的位操作命令字 09H = 0000 1001B 中 D3D2D1=100 选中 PC4、D0=1 表示置位,即把该联络线置为高电平
连接实验箱执行代码,逻辑开关代表三位二进制数,发送脉冲信号后其对应的十进制编号的 LED 灯点亮,显示输入的二进制数字
# 方式 1 中断输入
按方式 1 输入电路连线。编程每按一次单脉冲按钮产生一个正脉冲,使 8255 产生一次中断请求,CPU 进行一次中断服务:读取逻辑电平开关预置的 ASCII 码,在屏幕上显示其对应的字符,输出 NEUQ2022:
| 接线 | |
|---|---|
| 8255/JP6(PA7---PA0) | 逻辑开关/JP1(K7---K0) |
| 8255/PC4 | 单脉冲/正脉冲 |
| 8255/PC3 | 总线区/SIRQx |
| 8255/CS | I/O译码/Y1(288H---28FH) |
io3-3.asm
data segment
ioa equ 288h
iob equ 289h
ioc equ 28ah
iok equ 28bh
t1 db 1,2,4,8,16,32,64,128
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,iok
mov al,0afh
out dx,al
mov al,4
out dx,al
readb:
mov dx,ioc
in al,dx
test al,00000010b
jz readb
mov dx,iob
in al,dx
and al,00000111b
mov bx,offset t1
xlat
mov dx,ioa
out dx,al
mov ah,1
int 16h
jz readb
mov ah,4ch
int 21h
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
控制字 0AFH = 1010 1111B:D7=1 为方式控制字,D6D5=01 表示 A 组方式 1、D4=0 表示 A 口输出、D3=1 表示 PC7 与 PC6 输出;D2=0 表示 B 组方式 0、D1=1 表示 B 口输入、D0=1 表示 PC3~PC0 输入。随后写入的位操作命令字 04H = 0000 0100B 中 D3D2D1=010 选中 PC2、D0=0 表示复位
连接实验箱执行代码,现象如下:
# ADC0809 模数转换
ADC0809 是 8 通道 8 位逐次逼近型模数转换器,启动一次转换约需 100μs,EOC 为转换结束信号;实验中只用 IN0 一路,端口地址为 298H
按转换结果的读取方式,本实验分为三种方法:延时法在启动转换后先执行一段延时程序,等转换结束后再读结果;查询法在启动转换后不断检测 EOC 的状态,转换一结束立即读结果;中断法则把 EOC 经中断控制器接到 CPU,转换结束时以中断方式通知 CPU 来取结果。前两种方法都要由 CPU 反复等待,第三种由硬件通知,效率最高
延时法:
查询法:按照下图进行连线,使用查询法检测 EOC 状态,编程采集 IN0 输入的电压,在屏幕上以 16 进制显示出转换后的数据
中断法:
# 延时法实验
io4-1.asm
data segment
in0 equ 298h
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
s1:
mov dx,in0
out dx,al
mov cx,0ffh
s:loop s
mov dx,in0
in al,dx
mov bl,al
mov cl,4
shr bl,cl
call disp
and al,0fh
mov bl,al
call disp
mov dl,20h
mov ah,2
int 21h
mov ah,1
int 16h
jz s1
mov ah,4ch
int 21h
disp proc
push bx
push ax
push dx
mov dl,bl
cmp dl,9
jbe t
add dl,7
t:add dl,30h
mov ah,2
int 21h
pop dx
pop ax
pop bx
ret
disp endp
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
实验现象:随着手动旋转旋钮,控制外部计时器芯片的输出脉冲宽度,改变 ADC0809 内部采样电容的电压稳定时间,显示器输出 00-ff
- 输出脉冲宽度较小时,采样电容电压稳定时间较短,转换速度较快但精度较低
- 输出脉冲宽度增大时,采样电容电压稳定时间变长,转换速度变慢但精度提高
# 查询法实验
io4-2.asm
data segment
in0 equ 298h
ioc equ 28ah
iok equ 28bh
data ends
code segment
assume cs:code,ds:data
start:
mov ax,data
mov ds,ax
mov dx,iok
mov al,89h
out dx,al
s1:
mov dx,in0
out dx,al
readc:
mov dx,ioc
in al,dx
test al,00000001b
jz readc
mov dx,in0
in al,dx
mov bl,al
mov cl,4
shr bl,cl
call disp
and al,0fh
mov bl,al
call disp
mov dl,20h
mov ah,2
int 21h
mov ah,1
int 16h
jz s1
mov ah,4ch
int 21h
disp proc
push bx
push ax
push dx
mov dl,bl
cmp dl,9
jbe t
add dl,7
t:add dl,30h
mov ah,2
int 21h
pop dx
pop ax
pop bx
ret
disp endp
code ends
end start
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
实验现象:显示器同样输出 00-ff,与延时法相比,查询法的转换速度更稳定,不受延时时间影响
- 查询周期较小时,输出信号精度较低、数字信号误差较大;查询周期增大,精度提高、误差减小;查询周期达到一定值后精度不再明显提高,此时芯片内部的状态寄存器已足够稳定,不受外界干扰
- 查询周期较短时转换速度较快,查询周期增大则转换速度变慢;相对延时法,查询法的转换速度一般比较稳定
# 中断法实验
io4-3.asm
DATA SEGMENT
in0 equ 298h
DATA ENDS
CODE SEGMENT
ASSUME CS:CODE,DS:DATA
START:
MOV AX,CS
MOV DS,AX
MOV DX,OFFSET INT3
MOV AX,250BH
INT 21H
IN AL,21H
AND AL,0F7H
OUT 21H,AL
MOV dx,in0
out dx,al
LL: JMP LL
INT3:
MOV AX,DATA
MOV DS,AX
mov dx,in0
in al,dx
mov bl,al
mov cl,4
shr bl,cl
call disp
and al,0fh
mov bl,al
call disp
mov dl,20h
mov ah,2
int 21h
mov dx,in0
out dx,al
MOV AL,20H
OUT 20H,AL
IRET
disp proc
push bx
push ax
push dx
mov dl,bl
cmp dl,9
jbe t
add dl,7
t:add dl,30h
mov ah,2
int 21h
pop dx
pop ax
pop bx
ret
disp endp
CODE ENDS
END START
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
实验现象:显示器输出 00-ff
- 转换精度和稳定性:由芯片内部自动控制转换与输出数字信号,提高了转换精度和稳定性,减小了干扰和误差
- 转换速度:相对查询法和延时法更快,无需人工干预和等待查询周期
- 中断控制:通过中断控制器实现自动转换和输出数字信号,可以控制中断方式、中断优先级和中断响应等参数
# 实验总结
心得方面,这类实验的难点往往不在汇编本身,而在接线与初始化:插线要插稳,每次改完线路都要重新做一次硬件检测;中断实验里设置中断向量、清除 IMR 对应位、发送 EOI 三步缺一不可;控制字写错一位,现象往往就完全不对
